packaging/aur/PKGBUILD (1153B)
1 # Maintainer: sqzer (hyukjin an) <110329244+sqzer-x@users.noreply.github.com>
2
3 pkgname=ommp
4 pkgver=0.1.3
5 pkgrel=1
6 pkgdesc="Oh My Music Player — a standalone terminal music player"
7 arch=('x86_64' 'aarch64')
8 url="https://github.com/sqzer-x/ommp"
9 license=('Apache-2.0')
10 depends=('gcc-libs' 'glibc' 'alsa-lib')
11 makedepends=('cargo')
12 optdepends=(
13 'ttf-nerd-fonts-symbols: interface icons'
14 )
15 source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
16 sha256sums=('d9b44c27e0e0a537c704c575e8838fdc885f418bc7e750fa6946cb391efe3bfb')
17
18 prepare() {
19 cd "$pkgname-$pkgver"
20 export RUSTUP_TOOLCHAIN=stable
21 cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
22 }
23
24 build() {
25 cd "$pkgname-$pkgver"
26 export RUSTUP_TOOLCHAIN=stable
27 export CARGO_TARGET_DIR=target
28 cargo build --frozen --release
29 }
30
31 check() {
32 cd "$pkgname-$pkgver"
33 export RUSTUP_TOOLCHAIN=stable
34 cargo test --frozen
35 }
36
37 package() {
38 cd "$pkgname-$pkgver"
39 install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$pkgname"
40 install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
41 install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname/" README.md
42 }